momentu.f90

Go to the documentation of this file.

! Copyright (C) 2018 T. Mueller, J. K. Dewhurst, S. Sharma and E. K. U. Gross.
! This file is distributed under the terms of the GNU General Public License.
! See the file COPYING for license details.

subroutine momentu
use modmain
use modulr
use modtest
implicit none
! local variables
integer idm,is,ias
integer nrc,nrci,ifq,ir
real(8) t1
! automatic arrays
real(8) rfft(nqpt)
complex(8) zfft(nfqrz)
! external functions
complex(8), external :: zfmtint
if (.not.spinpol) return
! calculate muffin-tin moments
mommttot(:)=0.d0
do idm=1,ndmag
  do ias=1,natmtot
    is=idxis(ias)
    nrc=nrcmt(is)
    nrci=nrcmti(is)
    do ifq=1,nfqrz
      zfft(ifq)=zfmtint(nrc,nrci,wr2cmt(:,is),magqmt(:,ias,idm,ifq))
    end do
    mommt(idm,ias)=zfft(1)%re
    mommttot(idm)=mommttot(idm)+mommt(idm,ias)
    call rzfftifc(3,ngridq,1,rfft,zfft)
    mommtru(idm,ias,1:nqpt)=rfft(1:nqpt)
! store the muffin-tin moments in Q-space
    mommtqu(idm,ias,1:nfqrz)=zfft(1:nfqrz)
  end do
end do
! calculate the interstitial and total moments
t1=omega/ngtc
do idm=1,ndmag
  do ifq=1,nfqrz
    zfft(ifq)=t1*sum(magqir(1:ngtc,idm,ifq)*cfrc(1:ngtc))
  end do
  momir(idm)=zfft(1)%re
  momtot(idm)=mommttot(idm)+momir(idm)
  call rzfftifc(3,ngridq,1,rfft,zfft)
  do ir=1,nqpt
    momirru(idm,ir)=rfft(ir)
    momtotru(idm,ir)=sum(mommtru(idm,1:natmtot,ir))+momirru(idm,ir)
  end do
! store the interstitial moments in Q-space
  momirqu(idm,1:nfqrz)=zfft(1:nfqrz)
! store the total moments in Q-space
  do ifq=1,nfqrz
    momtotqu(idm,ifq)=sum(mommtqu(idm,1:natmtot,ifq))+momirqu(idm,ifq)
  end do
end do
! total moment magnitude
momtotm=merge(norm2(momtot(1:3)),abs(momtot(1)),ncmag)
! write the muffin-tin moments to test file
call writetest(770,'ULR total moments',nv=ndmag*nqpt,tol=2.d-2,rva=momtotru)
end subroutine