genpmat.f90

Go to the documentation of this file.

! Copyright (C) 2015 J. K. Dewhurst, S. Sharma and E. K. U. Gross.
! This file is distributed under the terms of the GNU General Public License.
! See the file COPYING for license details.

subroutine genpmat
use modmain
use modmpi
use modomp
implicit none
! local variables
integer ik,nthd
! allocatable arrays
complex(8), allocatable :: pmat(:,:,:)
if (mp_mpi) write(*,*)
! synchronise MPI processes
call mpi_barrier(mpicom,ierror)
call holdthd(nkpt/np_mpi,nthd)
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(pmat) &
!$OMP NUM_THREADS(nthd)
allocate(pmat(nstsv,nstsv,3))
!$OMP DO SCHEDULE(DYNAMIC)
do ik=1,nkpt
! distribute among MPI processes
  if (mod(ik-1,np_mpi) /= lp_mpi) cycle
!$OMP CRITICAL(genpmat_)
  write(*,'("Info(genpmat): ",I0," of ",I0," k-points")') ik,nkpt
!$OMP END CRITICAL(genpmat_)
! generate the momentum matrix elements for k-point ik
  call genpmatk(ik,pmat)
! write the matrix elements to file
  call putpmat(ik,pmat)
end do
!$OMP END DO
deallocate(pmat)
!$OMP END PARALLEL
call freethd(nthd)
! synchronise MPI processes
call mpi_barrier(mpicom,ierror)
end subroutine