energycore.f90

Go to the documentation of this file.

! Copyright (C) 2007-2008 J. K. Dewhurst, S. Sharma and E. K. U. Gross.
! This file is distributed under the terms of the GNU Lesser General Public
! License. See the file COPYING for license details.

subroutine energycore
use modmain
implicit none
! local variables
integer ist,is,ias,nr,nri
real(8) sm
! automatic arrays
real(8) vr(nrmtmax),fr(nrmtmax)
! zero the sum of core eigenvalues
evalsmc=0.d0
! zero the core Kohn-Sham potential energy
engyvsc=0.d0
sm=0.d0
do ias=1,natmtot
  is=idxis(ias)
  nr=nrmt(is)
  nri=nrmti(is)
! add to sum of core eigenvalues
  do ist=1,nstsp(is)
    if (spcore(ist,is)) evalsmc=evalsmc+occcr(ist,ias)*evalcr(ist,ias)
  end do
! extract the l = m = 0 part of the Kohn-Sham potential
  call rfmtlm(1,nr,nri,vsmt(:,ias),vr)
! multiply by core density and integrate
  if (spincore) then
! spin-polarised core
    fr(1:nr)=rhocr(1:nr,ias,1)+rhocr(1:nr,ias,2)
    engyvsc=engyvsc+sum(fr(1:nr)*vr(1:nr)*wr2mt(1:nr,is))
  else
! spin-unpolarised core
    engyvsc=engyvsc+sum(rhocr(1:nr,ias,1)*vr(1:nr)*wr2mt(1:nr,is))
  end if
! frozen core case
  if (frzncore) sm=sm+sum(rhocr(1:nr,ias,1)*vrsp(1:nr,is)*wr2mt(1:nr,is))
end do
! core electron kinetic energy
engyknc=evalsmc-merge(sm/y00,engyvsc,frzncore)
end subroutine