chargeu.f90

Go to the documentation of this file.

! Copyright (C) 2019 T. Mueller, J. K. Dewhurst, S. Sharma and E. K. U. Gross.
! This file is distributed under the terms of the GNU General Public License.
! See the file COPYING for license details.

subroutine chargeu
use modmain
use modulr
use modtest
implicit none
! local variables
integer is,ias,nrc,nrci,ifq,ir
real(8) t1
! automatic arrays
real(8) rfft(nqpt)
complex(8) zfft(nfqrz)
! external functions
complex(8), external :: zfmtint
! calculate muffin-tin charges
chgmttot=0.d0
do ias=1,natmtot
  is=idxis(ias)
  nrc=nrcmt(is)
  nrci=nrcmti(is)
  do ifq=1,nfqrz
    zfft(ifq)=zfmtint(nrc,nrci,wr2cmt(:,is),rhoqmt(:,ias,ifq))
  end do
  chgmt(ias)=zfft(1)%re
  chgmttot=chgmttot+chgmt(ias)
  call rzfftifc(3,ngridq,1,rfft,zfft)
  chgmtru(ias,1:nqpt)=rfft(1:nqpt)
! store the muffin-tin charges in Q-space
  chgmtqu(ias,1:nfqrz)=zfft(1:nfqrz)
end do
! calculate interstitial and total charges
t1=omega/ngtc
do ifq=1,nfqrz
  zfft(ifq)=t1*sum(rhoqir(1:ngtc,ifq)*cfrc(1:ngtc))
end do
chgir=zfft(1)%re
chgcalc=chgmttot+chgir
call rzfftifc(3,ngridq,1,rfft,zfft)
do ir=1,nqpt
  chgirru(ir)=rfft(ir)
  chgtotru(ir)=sum(chgmtru(1:natmtot,ir))+chgirru(ir)
end do
! store the interstitial charge in Q-space
chgirqu(1:nfqrz)=zfft(1:nfqrz)
! store the total charge in Q-space
do ifq=1,nfqrz
  chgtotqu(ifq)=sum(chgmtqu(1:natmtot,ifq))+chgirqu(ifq)
end do
! write muffin-tin charges to file
call writetest(730,'ULR total charges',nv=nqpt,tol=5.d-5,rva=chgtotru)
end subroutine