bdipoleu.f90

Go to the documentation of this file.

! Copyright (C) 2024 Wenhan Chen, J. K. Dewhurst and S. Sharma.
! This file is distributed under the terms of the GNU General Public License.
! See the file COPYING for license details.

subroutine bdipoleu
use modmain
use modulr
implicit none
! local variables
integer iq,ifq
real(8) cb,t0
complex(8) zv(3),z1
if (.not.ncmag) then
  write(*,*)
  write(*,'("Error(bdipoleu): non-collinear magnetism required for inclusion &
   &of the dipole field")')
  write(*,*)
  stop
end if
! prefactor for the electron spin dipole magnetic field
cb=gfacte/(4.d0*solsc)
! prefector which allows term to be added directly to ULR Kohn-Sham B-field
t0=-bdipscf*fourpi*cb**2
do ifq=1,nfqrz
  iq=iqrzf(ifq)
! compute B(Q) = 4π (gₛ/4c)² [ m(Q) - Q (Q⋅m(Q))/Q² ]
  if (iq > 1) then
    zv(1:3)=momtotqu(1:3,ifq)/omega
    z1=vqc(1,iq)*zv(1)+vqc(2,iq)*zv(2)+vqc(3,iq)*zv(3)
    z1=z1/qc(iq)**2
    zv(1:3)=zv(1:3)-z1*vqc(1:3,iq)
    bdipq(1:3,ifq)=t0*zv(1:3)
  else
    bdipq(1:3,ifq)=0.d0
  end if
end do
end subroutine